3 berichten aan het bekijken - 1 tot 3 (van in totaal 3)
  • Q:
    Bijdrager
    stefonline

    Script om steeds de laatste pagina van een pdf te printen.

    Ik moet elke dag van best wel veel pdf’s telkens alleen de laatste pagina uitprinten. Best tijdrovend en dus ideaal als dat te automatiseren is.

    Ik zoek dus een script / mapactie die dit voor mij kan doen. Bestaat dit misschien al standaard of is er iets wat er op lijkt wat ik aan kan passen.

    Of Kan iemand mij op weg helpen om een script(mapactie) te maken.

    Groet
    Stefan

    Bijdrager
    Verwijder

    VoilĂ 
    AppleScript weet niet hoeveel pagina’s er zijn dus is daar een truc voor nodig.

    on adding folder items to this_folder after receiving these_items
    	repeat with anItem in these_items
    		tell application "Preview"
    			try
    				activate
    				set aDocument to open anItem
    				set aPage to last word of ((name of window 1) as text) -- xx.pdf (pagina 1 van 45)
    				print aDocument with properties {starting page:aPage, ending page:aPage, target printer:"PDFwriter"} without print dialog
    				close aDocument without saving
    			on error the error_message number the error_number
    				display dialog "Error: " & the error_number & ". " & the error_message buttons {"Cancel"} default button 1
    			end try
    		end tell
    	end repeat
    end adding folder items to

    Gebruiksaanwijzing:
    Plak in Scripteditor
    Vervang PDFwriter door de naam van de printer
    Bewaar als script
    Plaats het script in /Users/naamvandegebruiker/Library/Scripts/Folder Action Scripts/
    Configureer de mapactie
    Probeer of het werkt, ik zal duimen.

    Bijdrager
    stefonline

    @Willemien

    Helemaal TOP!!!

3 berichten aan het bekijken - 1 tot 3 (van in totaal 3)

Je moet ingelogd zijn om een reactie op dit onderwerp te kunnen geven.